Email-Vorlage versenden

Dieses Beispiel zeigt, wie man eine Vorlage anhand des Betreffs findet. Von der Vorlage wird dann eine Kopie erstellt und angezeigt. Diese können Sie ändern und senden, ohne dass das Original verändert wird.

Erstellen Sie einen Unterordner im Ordner Entwürfe, benennen Sie den Meine Vorlagen und speichern Sie Ihre Vorlagen dort, wo die nicht stören. Die Vorlage selbst heißt im Beispiel 'Vorlage 1'. Tragen Sie da den Betreff Ihrer Vorlage ein. Aufrufen können Sie das Makro z.B. über ALT+F8. Wenn Sie auf diese Weise mehrere Vorlagen verwenden wollen, vervielfältigen Sie einfach die Draft_1-Funktion und geben Sie jeder Funktion einen beliebigen, eindeutigen Namen.

(Hier gibt es noch ein ähnliches Beispiel)

  So fügen Sie Makros in Outlook ein

Private Const TemplateFolder As String = "Meine Vorlagen"

Public Sub Draft_1()
  LoadTemplate "Vorlage 1"
End Sub

Private Sub LoadTemplate(Name As String)
  Dim Ns As Outlook.NameSpace
  Dim Folder As Outlook.MAPIFolder
  Dim Mail As Outlook.MailItem

  Set Ns = Application.GetNamespace("MAPI")
  Set Folder = Ns.GetDefaultFolder(olFolderDrafts)
  Set Folder = Folder.Folders(TemplateFolder)
  Set Mail = LoadTemplate_Ex(Folder.Items, Name)
  If Not Mail Is Nothing Then
    Mail.Display
  Else
    MsgBox "Keine Vorlage mit Betreff: '" & Name & "' gefunden"
  End If
End Sub

Private Function LoadTemplate_Ex(Items As Outlook.Items, Name As String) As Outlook.MailItem
  On Error Resume Next
  Dim Mail As Outlook.MailItem
  Set Mail = Items.Find("[subject]=" & Chr(34) & Name & Chr(34))
  If Not Mail Is Nothing Then
    Set LoadTemplate_Ex = Mail.Copy
  End If
End Function