| | Awarded by
Microsoft since 2005: |  |
| | VBOffice Info | | Besucher | 1409129 | | Aufrufe | 5189351 |
| |
|
| |
| Autor: Michael Bauer | Homepage | | Datum: 24.04.2007 | Zugriffe: 28897 | | | | Beschreibung
Standardmäßig werden alle Mails im Ordner 'Gesendete Objekte' gespeichert. Über den Optionendialog einer geöffneten Mail können Sie auch manuell eine davon abweichende Einstellung vornehmen.
Wenn Sie aber grundsätzlich alle Mails in einem vom Standard abweichenden Ordner speichern wollen, dann geht das nur mit ein paar Zeilen Code.
Beispiel #1 zeigt, wie alle Mails in einem Unterordner des Posteingangs namens 'Ablage' gespeichert werden. Ausgenommen davon sind die Mails, die nach dem Senden gelöscht werden sollen.
Beispiel #2 dagegen zeigt einen Dialog zur manuellen Auswahl des Ordners an.
Beispiel #3 prüft den Namen des Sendekontos und speichert die E-Mail je nach Konto in verschiedenen, vorher festgelegten Unterordnern des Posteingangs. Dieses Beispiel funktioniert so erst ab Outlook 2007! |
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
If TypeOf Item Is Outlook.MailItem Then
SaveSentMail Item
End If
End Sub
Private Sub SaveSentMail(Item As Outlook.MailItem)
Dim Inbox As Outlook.MAPIFolder
Dim Subfolder As Outlook.MAPIFolder
If Item.DeleteAfterSubmit = False Then
Set Inbox = Application.Session.GetDefaultFolder(olFolderInbox)
Set Subfolder = Inbox.Folders("Ablage")
Set Item.SaveSentMessageFolder = Subfolder
End If
End Sub
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
If TypeOf Item Is Outlook.MailItem Then
Cancel = Not SaveSentMail(Item)
End If
End Sub
Private Function SaveSentMail(Item As Outlook.MailItem) As Boolean
Dim F As Outlook.MAPIFolder
If Item.DeleteAfterSubmit = False Then
Set F = Application.Session.PickFolder
If Not F Is Nothing Then
Set Item.SaveSentMessageFolder = F
SaveSentMail = True
End If
End If
End Function
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
If TypeOf Item Is Outlook.MailItem Then
SaveSentMail Item
End If
End Sub
Private Sub SaveSentMail(Item As Outlook.MailItem)
Dim Inbox As Outlook.Folder
Dim SubFolder As Outlook.Folder
If Item.DeleteAfterSubmit = False Then
Set Inbox = Application.Session.GetDefaultFolder(olFolderInbox)
Select Case LCase$(Item.SendUsingAccount.DisplayName)
Case "mvp"
Set SubFolder = Inbox.Folders("ablage")
Case "sample"
Set SubFolder = Inbox.Folders("another sample folder")
End Select
If Not SubFolder Is Nothing Then
Set Item.SaveSentMessageFolder = SubFolder
End If
End If
End Sub
|
| | |
| | |  | ReplyAll warnt Sie, bevor Sie unbeabsichtigt allen Empfängern
einer E-Mail antworten oder wenn Sie ein vertraulicher BCC-Empfänger der E-Mail ... [weiter] |
| | |  | Blitzschneller Zugriff auf die Hauptkategorienliste, gemeinsame Kategorien im Netzwerk, eine Erinnerungsfunktion ... [weiter] |
| | |  | SAM legt automatisch Absender, Signatur und Speicherort für gesendete Mails fest, z.B. anhand der ... [weiter] |
| | |  | OLKeeper verhindert zuverlässig, dass Mitarbeiter Outlook schließen und dadurch Termine oder E-Mails ... [weiter] |
| | |
|
