VBOffice

Erste Seite einer Email drucken

So drucken Sie nur ausgewählte Seiten einer Email, statt die ganze Email zu drucken.

Zuletzt geändert: 12.10.2015 | Aufrufe: 21.407  | #156
◀ Vorheriges Beispiel Nächstes Beispiel ▶

Inhalt

OLKeeper OLKeeper
Der OLKeeper verhindert zuverlässig, dass Sie Microsoft Outlook unbeabsichtigt schließen und so etwa wichtige Emails verpassen würden.

Erste Seite drucken

Das MailItem-Objekt aus Outlook kennt nur eine PrintOut-Funktion, mit der die ganze Email gedruckt wird. Es können keine Einstellungen vorgenommen werden, um z.B. nur eine bestimmte Seite zu drucken. Seit Outlook 2007 steht für Emails aber die sehr mächtige Bibliothek aus Word zur Verfügung, mit sehr einfach einzelne Seiten angesprochen werden können. Es ist zwar nicht möglich, eine Email direkt über Word auszudrucken, Sie können aber einfach den zu druckenden Inhalt in ein neues Word-Dokument kopieren und das dann ausdrucken.

Dieses Beispiel kopiert den kompletten Inhalt einer Email in ein neues Word-Dokument und druckt dann davon Seite 1 aus. Im Beispiel wird die erste Email, die im aktuellen Ordner ausgewählt ist, kopiert. Sie können die Funktion 'PrintFirstPage' aber auch aus einer Regel heraus aufrufen und so z.B. neue Emails, die bestimmte Kritieren erfüllen, automatisch drucken.

(Fügen Sie über Extras/Verweise einen Verweis auf die 'Microsoft Word x.0 Object Library' hinzu.)


tip  So fügen Sie Makros in Outlook ein
Public Sub TestPrintFirstPage()
  Dim Mail As Outlook.MailItem
  Set Mail = Application.ActiveExplorer.Selection(1)
  PrintFirstPage Mail
End Sub

Public Sub PrintFirstPage(Mail As Outlook.MailItem)
  Dim wdApp As Word.Application
  Dim wdDoc As Word.Document
  Dim olDoc As Word.Document
  
  Set wdApp = CreateObject("Word.Application")
  Set wdDoc = wdApp.Documents.Add(Visible:=True)
  
  Set olDoc = Mail.GetInspector.WordEditor
  olDoc.Range.copy
  wdDoc.Range.Paste
  
  wdDoc.PrintOut Range:=wdPrintFromTo, From:="1", To:="1"
  
  DoEvents
  wdDoc.Close False
  wdApp.Quit
End Sub
ReplyAll ReplyAll
Mit diesem Addin für Outlook erhalten Sie in verschiedenen Situationen eine Warnung, bevor Sie auf eine Email versehentlich allen anderen Empfängern antworten.

Markierten Text drucken

Dieses Beispiel druckt den in einer geöffneten Email markierten Text.

Public Sub PrintSelection()
  Dim wdApp As Word.Application
  Dim wdDoc As Word.Document
  Dim wdSelection As Word.Selection
  Dim wdWin As Word.Window
  Dim olDoc As Word.Document
  
  Set wdApp = CreateObject("Word.Application")
  Set wdDoc = wdApp.Documents.Add(Visible:=True)
  
  Set olDoc = Application.ActiveInspector.WordEditor
  Set wdWin = olDoc.Windows(1)
  Set wdSelection = wdWin.Selection
  wdSelection.Range.copy
  wdDoc.Range.Paste
  
  wdDoc.PrintOut
  
  DoEvents
  wdDoc.Close False
  wdApp.Quit
End Sub
Category-Manager Category-Manager
Mit dem Category-Manager können Sie Outlook Kategorien gruppieren, synchronisieren und filtern, neuen Emails automatisch die Kategorie des Absenders zuweisen und vieles mehr. Das Addin ist auch für IMAP geeignet.
email  Senden Sie eine Nachricht